در ستون کناری فایل اکسپلورر ویندوز، مواردی مثل کتابخانه‌های Pictures و Downloads به صورت پیش‌فرض موجود است و پارتیشن‌های هارددیسک نیز زیرمجموعه‌ی This PC است. برای دسترسی سریع‌تر می‌توانید فولدرهای پرکاربرد را در بخش Quick Access‌ قرار دهید. در این بخش قرار دادن درایوهای هارددیسک هم امکان‌پذیر است.

یک روش دیگر برای دسترسی سریع به پارتیشن‌های هارددیسک این است که درایورها در ستون کناری پین یا سنجاق کنید که نیاز به تغییراتی در رجیستری ویندوز دارد. در ادامه به روش پین کردن درایوها در ستون کناری File Explorer ویندوز ۱۰ می‌پردازیم.

اگر نخواهید پارتیشن پرکاربردی را به عنوان زیرمجموعه‌ی This PC‌‌ یا Quick Access در فایل اکسپلورر ویندوز ۱۰ داشته باشید، می‌توانید آن را با اسکریپتی که در ادامه بررسی می‌کنیم، پین کنید. اما قبل از هر چیز، از رجیستری ویندوز بکاپ تهیه کنید تا در صورت هر گونه اشتباه تصادفی، فرآیند قابل بازگشت باشد.

البته نیازی به بکاپ گرفتن از تمام رجیستری نیست، صرفاً از آدرس زیر بکاپ تهیه کنید:

HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\HideDesktopIcons\NewStartPanel

بنابراین با کلید میانبر Win + R پنجره‌ی Run‌ را باز کنید و دستور regedit را تایپ کرده و روی OK کلیک کنید. سپس مسیر فوق را کپی کرده و در نوار آدرس بالای پنجره‌ی رجیستری ادیتور پیست کنید و کلید Enter را فشار دهید. حال روی کلید یا فولدر NewStartPanel راست‌کلیک کنید و آن را در محل دلخواهی اکسپورت کنید.

پین کردن درایوها در ستون کناری File Explorer ویندوز ۱۰

برای پین کردن ساده و راحت می‌توانید از اسکریپت زیر استفاده کنید. لذا ابتدا Notepad‌ که اپلیکیشن ساده‌ی ویرایش فایل متنی در ویندوز است را اجرا کنید و کدهای زیر را در آن پیست کنید. سپس از منوی File و گزینه‌ی Save As برای ذخیره کردن خروجی استفاده کنید. نام فایل دلخواه است اما پسوند آن را bat بگذارید.

@ECHO OFF

SETLOCAL EnableExtensions

set "_icon=%%SystemRoot%%\system32\imageres.dll,27"

set "_name=D DataDisk"

set "_guid=ffffffff-ffff-ffff-0000-00000000000d"

set "_target=d:\\"

 

set "_regK=HKCU\Software\Classes\CLSID"

set "_regE=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer"

if NOT "%~1"=="" goto :deleAll

reg add %_regK%\{%_guid%} /ve /t REG_SZ /d "%_name%" /f

reg add %_regK%\{%_guid%}\DefaultIcon /ve /t REG_EXPAND_SZ /d %_icon% /f

reg add %_regK%\{%_guid%} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0x1 /f

reg add %_regK%\{%_guid%} /v SortOrderIndex /t REG_DWORD /d 0x42 /f

reg add %_regK%\{%_guid%}\InProcServer32 /ve /t REG_EXPAND_SZ /d %%systemroot%%\system32\shell32.dll /f

reg add %_regK%\{%_guid%}\Instance /v CLSID /t REG_SZ /d {0E5AAE11-A475-4c5b-AB00-C66DE400274E} /f

reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v Attributes /t REG_DWORD /d 0x11 /f

reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v TargetFolderPath /t REG_EXPAND_SZ /d "%_target%" /f

reg add %_regK%\{%_guid%}\ShellFolder /v FolderValueFlags /t REG_DWORD /d 0x28 /f

reg add %_regK%\{%_guid%}\ShellFolder /v Attributes /t REG_DWORD /d 0xF080004D /f

reg add %_regE%\Desktop\NameSpace\{%_guid%} /ve /t REG_SZ /d "%_name%" /f

reg add %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /t REG_DWORD /d 0x1 /f

 

:endlocal

ENDLOCAL

goto :eof

 

:deleAll

reg delete %_regK%\{%_guid%} /f

reg delete %_regE%\Desktop\NameSpace\{%_guid%} /f

reg delete %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /f

goto :endlocal

اکنون یک فایل Batch در اختیار دارید که در حقیقت یک اسکریپت ساده است. با اجرای این اسکریپت، درایو D سیستم شما به صورت یک گزینه در ستون کناری فایل اکسپلورر قرار می‌گیرد. برای اجرا می‌بایست آن را با دسترسی ادمین اجرا کنید. لذا روی فایل bat راست‌کلیک کنید و گزینه‌ی Run as administrator را انتخاب کنید. نتیجه‌ی اجرای اسکریپت را بررسی کنید:

آموزش پین کردن درایوهای هارددیسک در ستون کناری فایل اکسپلورر ویندوز

اما در مورد سایر درایوها مثل درایو C و E و غیره چه باید کرد؟

اسکریپت را در نوت‌پد باز کنید و خطوط ۳ الی ۶ را ویرایش کنید. این چهار خط به صورت زیر است:

set "_icon=%%SystemRoot%%\system32\imageres.dll,31"

set "_name=c SystemDisk"

set "_guid=ffffffff-ffff-ffff-0000-00000000000c"

set "_target=c:\\"

با نگاهی به ۴ خط فوق روشن است که کدام بخش‌ها می‌بایست تغییر کند:

  • خط اول آیکون درایو پین‌شده را مشخص می‌کند.
  • خط دوم نام درایو است که در اسکریپت ما از حرف C استفاده شده است و لذا می‌توانید سایر درایوها را به جای درایو C نیز پین کنید.
  • در خط سوم آخرین حرف که در مثال ما C است، می‌بایست به حرف مربوط به درایو تغییر کند.
  • خط آخر نیز آدرسی که با کلیک روی آیتم پین شده باز می‌شود را مشخص می‌کند که در مثال ما روت درایو C است اما می‌توانید روت سایر درایوها را با تغییر حرف C به D یا غیره، باز کنید.

روش حذف پارتیشن پین شده در سایدبار File Explorer ویندوز ۱۰

و اما روش حذف کردن درایوی که قبلاً پین شده: برای این کار ابتدا cmd را با دسترسی ادمین باز کنید. به عبارت دیگر در منوی استارت عبارت cmd را جستجو کرده و روی اولین نتیجه راست‌کلیک کنید و گزینه‌ی Run as administrator را انتخاب کنید. حال با فرمان CD فولدر کاری را به فولدری که اسکریپت در آن قرار گرفته، جابجا کنید. در نهایت دستور زیر را اجرا کنید و به جای NAME.bat از نام فایل اسکریپت استفاده کنید:

NAME.bat x

اگر چند پارتیشن را پین کرده‌اید، می‌بایست اسکریپت را هر بار تغییر بدهید و چند مرتبه دستور فوق را اجرا کنید تا یکایک پارتیشن‌های پین‌شده، حذف شوند.

اگر با این روش درایو حذف نمی‌شود، در رجیستری ویندوز کلید NewStartPanel را که قبلاً از آن بکاپ تهیه کرده‌اید را به حالت قبل بازگردانی کنید. یک روش دیگر این است که روی کلید موردبحث کلیک کنید و سپس در سمت چپ، مقدارهای جدیدی که اضافه شده را دیلیت کنید:

آموزش پین کردن درایوهای هارددیسک در ستون کناری فایل اکسپلورر ویندوز

در ادامه برای اطمینان بیشتر دستور ذکر شده را اجرا کنید و در نهایت سیستم را ری‌استارت کنید تا تغییرات اعمال شود.